@ECHO OFF
CLS
:LOOP
TITLE Installations/D‚sinstallation Des Cl‚s De Registre Fait Par HackChip
COLOR 2

SET EXEC_PERL="..\bin\perl"
SET EXEC_ZIP="..\bin\zip"
SET EXEC_UNZIP="..\bin\unzip"

SET DOSSIER_INS_SUPP_CDR="Installations - D‚sinstallation Des Cl‚s De Registre"
SET DOSSIER_EXTRACTION_FICHIERS_PATCHER=Fichiers_Patcher
SET DOSSIER_HOME="..\home"
SET ARCHIVE_FICHIERS_PATCHER=%DOSSIER_EXTRACTION_FICHIERS_PATCHER%.zip
SET CHEMIN_DOSSIER_SYSTEM32=%WINDIR%\system32
SET FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_BASH=kitdev-homebrew-ps2-bash.bat
SET FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_CMD=kitdev-homebrew-ps2-cmd.bat
SET FICHIER_INSTALLATION_CDR=Installation KitDev HomeBrew PlayStation 2.reg
SET FICHIER_DEINSTALLATION_CDR=D‚sinstallation KitDev HomeBrew PlayStation 2.reg
SET FICHIER_CYGWIN1_DLL=cygwin1.dll

SET LANG_CHOICE=Tapez le num‚ro de votre choix et appuyez sur Entr‚e: 
SET LANG_INS_SUPP_CDR=Des Cl‚s De Registre Du KitDev HomeBrew PlayStation 2
SET LANG_INSTALLATION_CDR=Installation
SET LANG_DEINSTALLATION_CDR=D‚sinstallation
SET LANG_CHOICE_ERREUR=n'est pas valide. S'il vous plaŚt essayer … nouveau.
SET LANG_CDR_ERREUR01=!!! Le fichier
SET LANG_CDR_ERREUR02=n'est pas pr‚sent !!!
SET LANG_QUITTER=Quitter

ECHO.                     ________________________________________________
ECHO                   +-/                                                \-+
ECHO                  / Installations/D‚sinstallation Des Cl‚s De Registre /
ECHO                 /                                                    /
ECHO                /                   Fait Par HackChip                /
ECHO                +-\_______________________________________________/-+
ECHO.
ECHO ============================http://www.metagames-eu.com=============================
ECHO.
ECHO.
ECHO 1. %LANG_INSTALLATION_CDR% %LANG_INS_SUPP_CDR%
ECHO 2. %LANG_DEINSTALLATION_CDR% %LANG_INS_SUPP_CDR%
ECHO 3. %LANG_QUITTER%

SET Choice=
ECHO.
SET /P Choice=%LANG_CHOICE%

IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%
ECHO.

IF /I '%Choice%'=='1' GOTO INSTALLATION_CDR
IF /I '%Choice%'=='2' GOTO DEINSTALLATION_CDR
IF /I '%Choice%'=='3' GOTO Fin
ECHO "%Choice%" %LANG_CHOICE_ERREUR%
ECHO.
PAUSE
CLS
GOTO Loop
CLS

:INSTALLATION_CDR
IF NOT EXIST "%ARCHIVE_FICHIERS_PATCHER%" (
ECHO %LANG_CDR_ERREUR01% "%ARCHIVE_FICHIERS_PATCHER%" %LANG_CDR_ERREUR02%
PAUSE
GOTO Fin
)
CD ..
SET CHEMIN_INSTALLATION_BAT=%CD:\=\/%
SET CHEMIN_INSTALLATION_REG=%CD:\=\\\\\\\%
CD %DOSSIER_INS_SUPP_CDR%
IF EXIST "%CHEMIN_DOSSIER_SYSTEM32%\%FICHIER_CYGWIN1_DLL%" (
RENAME "%CHEMIN_DOSSIER_SYSTEM32%\%FICHIER_CYGWIN1_DLL%" "%FICHIER_CYGWIN1_DLL%---BACKUP-POUR-KITDEV-PS2"
)
IF EXIST "%ARCHIVE_FICHIERS_PATCHER%" (
%EXEC_UNZIP% "%ARCHIVE_FICHIERS_PATCHER%"
%EXEC_PERL% -pi -e "s/{__CHEMIN__}/%CHEMIN_INSTALLATION_BAT%/g" "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%\%FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_BASH%"
%EXEC_PERL% -pi -e "s/{__CHEMIN__}/%CHEMIN_INSTALLATION_BAT%/g" "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%\%FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_CMD%"
%EXEC_PERL% -pi -e "s/{__CHEMIN__}/%CHEMIN_INSTALLATION_REG%/g" "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%\%FICHIER_INSTALLATION_CDR%"
START /WAIT REGEDIT /S "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%\%FICHIER_INSTALLATION_CDR%"
COPY /Y "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%\%FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_BASH%" ..\
COPY /Y "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%\%FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_CMD%" ..\
RD /S /Q "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%"
)
GOTO Fin

:DEINSTALLATION_CDR
IF NOT EXIST "%ARCHIVE_FICHIERS_PATCHER%" (
ECHO %LANG_CDR_ERREUR01% "%ARCHIVE_FICHIERS_PATCHER%" %LANG_CDR_ERREUR02%
PAUSE
GOTO Fin
)
IF EXIST "%ARCHIVE_FICHIERS_PATCHER%" (
%EXEC_UNZIP% "%ARCHIVE_FICHIERS_PATCHER%"
START /WAIT REGEDIT /S "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%\%FICHIER_DEINSTALLATION_CDR%"
RD /S /Q %DOSSIER_HOME%
DEL /F /Q ..\%FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_BASH%
DEL /F /Q ..\%FICHIER_DEMARRAGE_KIT_DEV_HOMEBREW_PS2_CMD%
RD /S /Q "%DOSSIER_EXTRACTION_FICHIERS_PATCHER%"
)
GOTO Fin

:Fin
CLS
